graph ← graph ##.remnode vertex             ⍝ Remove vertex ⍵ from graph ⍺.

Returns a new graph with the target vertex removed.

Examples:

      disp a                            ⍝ graph "a".
┌→──┬─┬───┬───┬─┐ 
│2 3│3│2 4│1 5│3│
└~─→┴─┴~─→┴~─→┴─┘ 

      disp a remnode 3                  ⍝ ... with vertex 3 removed.
┌→┬─┬───┬─┐ 
│2│0│1 4│0│
└→┴⊖┴~─→┴⊖┘ 

      disp a remnode foldl 1   v        ⍝ remove first vertex from "a".
┌→┬───┬─┬─┐ 
│2│1 3│4│2│
└→┴~─→┴→┴→┘ 

      disp a remnode foldl 1 1          ⍝ remove first two vertices from "a".
┌→┬─┬─┐ 
│2│3│1│
└→┴→┴→┘ 

      disp a remnode foldl 5 4          ⍝ remove last two vertices from "a".
┌→──┬─┬─┐ 
│2 3│3│2│
└~─→┴→┴→┘ 

      drop←{⍺ remnode foldl ⍵/⍳1}       ⍝ vertex dropping function.

      disp a drop 1                     ⍝ drop 1 vertex from "a".
┌→┬───┬─┬─┐ 
│2│1 3│4│2│
└→┴~─→┴→┴→┘ 

      disp a drop 2                     ⍝ drop 2 vertices from "a".
┌→┬─┬─┐ 
│2│3│1│
└→┴→┴→┘ 

      disp a drop 5                     ⍝ drop 5 vertices from "a".
┌⊖┐
│0│
└⊖┘

See also: Graphs insnode popnode remlink

Back to: contents

Back to: Dyalog APL

Trouble seeing APL font?