# Unforgettable Numbers

Professor Kip Murray asked on the J Forum for the “unforgettable” times seen on a 24-hour digital clock.

The problem is that every number has something notable about it, so that each number is “unforgettable” and consequently it’s hard to remember any single one of them.

` 0000 ` all zeros
` 0001 ` first counting number
` 0002 ` first prime number
` 0003 ` first odd prime number
` 0004 ` first composite number
` ... `

``````      ⎕rl←7*5 ⋄ 24 60⊤¯1+?×/24 60
6 59``````

` 0659 ` the time I wake up if the alarm was set at 0700 ☺

You may have heard of the following story about Hardy and Ramanujan. One day Hardy took a taxi to visit Ramanujan. On arriving, Hardy told Ramanujan that the taxi had the thoroughly unremarkable 4-digit number `n` on its licence plate. Ramanujan immediately remarked that `n` is the first number that … . I forget what `n` or the property was, something like `n` is the first number that can be written as the sum of two perfect cubes in two different ways, something typically Ramanujanian.

Yes, that was it:

``````      c←3*⍨⍳200           ⍝ cubes of numbers 1..200
t←(∘.≤⍨⍳≢c) × ∘.+⍨c
⍝ upper triangle of the addition table of these cubes

e←(,t){⍺⍵}⌸,⍳⍴t     ⍝ unique sums and their indices
e←(2=≢¨e[;2])⌿e     ⍝ sums that derive two different ways
e
┌───────┬─────────────────┐
│1729   │┌────┬────┐      │
│       ││1 12│9 10│      │
│       │└────┴────┘      │
├───────┼─────────────────┤
│1092728│┌─────┬─────┐    │
│       ││1 103│64 94│    │
│       │└─────┴─────┘    │
├───────┼─────────────────┤
...
├───────┼─────────────────┤
│5472152│┌───────┬───────┐│
│       ││102 164│128 150││
│       │└───────┴───────┘│
└───────┴─────────────────┘

e⌷⍨(⊢⍳⌊/)e[;1]      ⍝ the row with the smallest sum
┌────┬───────────┐
│1729│┌────┬────┐│
│    ││1 12│9 10││
│    │└────┴────┘│
└────┴───────────┘
+/ 1 12 * 3         ⍝ check the sums
1729
+/ 9 10 * 3
1729
``````

Now that I have worked out the number I can find the story on the net. On hearing the story, J.E. Littlewood remarked that “every positive integer is one of Ramanujan’s personal friends”.

P.S. In my youth, when I needed to remember a (5-digit) number for a time, I computed its largest prime factor by mental calculation. Try it and you’ll see why it works.

Translated and updated from a J Wiki essay which first appeared on 2009-08-22.

## 2 thoughts on “Unforgettable Numbers”

1. I tried the prime factorisation trick and it worked: by the time I’d worked out the factors, I no longer needed to remember the number!

2. Singular numbers are great, but so are sequences of numbers! Thankfully oeis.org (The Online Encyclopedia of Integer Sequences) maintains these with a searching functionality (type in a few numbers and it will suggest matching (or closely matching) integer sequences).